10.4 SI() avec deux conditions ou plus

Dans certains cas, vous aurez besoin de faire deux tests afin de déterminer ce qui doit être entré dans une cellule.

Par exemple, vous pourriez écrire « Accepté » pour les gens dont l'âge est situé entre 25 et 30 ans. limites incluses.

Deux conditions doivent donc être respectées : l'âge doit être supérieur ou égal à 25 et l'âge doit être inférieur ou égal à 30.

Voici quelques techniques permettant de tester deux conditions.

Fonction ET()

La fonction ET() combinée à la fonction SI() permet de vérifier deux conditions.

Les deux conditions doivent être vraies pour que la cellule prenne la valeur donnée par le deuxième argument du SI().

Si l'une ou l'autre des conditions n'est pas vraie, la cellule prendra la valeur donnée par le troisième argument du SI().

Dans l'exemple suivant, le mot « Accepté » sera inscrit dans la cellule E5 si l'âge entré dans la cellule D5 est plus grand ou égal à 25 ET qu'il est plus petit ou égal à 30. Si l'une ou l'autre de ses conditions est fausse, il n'y aura que du vide dans la cellule E5 (le vide étant indiqué par "").

La formule à entrer en E5 est :

=SI(ET(D5>=25;D5<=30);"Accepté";"")

Fonction OU()

La fonction OU() combinée à la fonction SI() permet elle aussi de tenir compte de deux conditions mais cette fois, elle vérifie si l'une ou l'autre des conditions est vraie.

Dans l'exemple suivant, une personne est éligible si elle est âgée d'au moins 60 ans OU si elle a au moins 25 ans d'expérience.

La formule à entrer en F5 est la suivante :

=SI(OU(D5>=60;E5>=25);"oui";"non")

Fonctions SI() imbriquées

Il est possible d’imbriquer des fonctions SI() afin d'offrir plus de deux alternatives. La technique consiste à entrer les arguments suivants :

• 1er argument : la condition du SI().
• 2e argument : la valeur que prendra la cellule si la condition est vraie.
• 3e argument : une nouvelle fonction SI().
  
  • 1er argument du 2e SI() : la nouvelle condition à vérifier. Elle ne sera vérifiée que si la première condition était fausse.
  • 2e argument du 2e SI() : la valeur que prendra la cellule si la 2e condition est vraie.
  • 3e argument du 2e SI() : la valeur que prendra la cellule si la 2e condition est fausse. 

Par exemple, on pourra afficher dans quelle zone d'âge se trouve une facture selon si elle a 30 jours ou moins, entre 31 et 60 jours ou plus de 60 jours.

La formule à entrer en E5 va comme suit :

=SI(D5<=30;"30 jours";SI(D5<=60;"60 jours";"*** Souffrance ***"))

Fonction SI.CONDITIONS()

La fonction SI.CONDITIONS() offre une autre alternative pour faire plusieurs tests afin de déterminer ce qui doit être entré dans une cellule. 

Elle est équivalente aux SI() imbriqués mais elle est plus facile à lire.

Elle permet de tester jusqu'à 127 conditions.

L'ordre dans lequel les conditions sont entrées est très important puisque la deuxième condition ne sera évaluée que si la première est fausse.

SI.CONDITIONS() utilise ces arguments :

• 1er argument : la première condition à évaluer.
• 2e argument : la valeur que prendra la cellule si la condition est vraie.
• 3e argument : la condition à évaluer si la condition d'avant était fausse.
• 4e argument : la valeur que prendra la cellule si la 2e condition est vraie.
• ... : on peut entrer plusieurs autres paires condition-valeur.
• avant-dernier argument : VRAI : cette condition est toujours évaluée à vrai et permet d'afficher la valeur spécifiée comme dernier argument.
• dernier argument : puisque l'avant-dernier argument est VRAI et qu'il est atteint seulement si aucune autre condition n'a été respectée, ceci est la valeur que prendra la cellule si toutes les conditions d'avant sont fausses.

Ainsi, la formule de l'exemple précédent :

=SI(D5<=30;"30 jours";SI(D5<=60;"60 jours";"*** Souffrance ***"))

peut être réécrite comme suit :

=SI.CONDITIONS(D5<=30;"30 jours";D5<=60;"60 jours"; VRAI;"*** Souffrance ***")